Track User

[[R]]

• This addon will let you see the other nicks from the users they used when they join and also when u make right click on any nick on the nicklist and choose  Track Users --- > View Other Nicknames
  

How to load the addon on your mIRC script (choose either 1 or 2)

1- Go on Tools on the MenuBar - Script Editor - Remote - File - New then copy the code down and paste it there then press Ok.

2- Download the Track User.mrc down, Put it on the mirc folder and go on Tools on the MenuBar - Script Editor --- > Remote - File  - Load and then choose the place of the Track User.mrc and then press Open then Ok.

Code

Code:

ON *:START: {
  ; Create a hash table and load the saved user data
  hmake trackusers 10
  if ($isfile(trackusers.dat)) {
    hload trackusers trackusers.dat
  }
}
on *:JOIN:#: {
  ; Check if there are any nicknames for this mask
  if ($hget(trackusers,$address($nick,2))) {
    var %n = $ifmatch
    ; Delete the current nickname from the list of used nicknames
    if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
    else { var %d = %n }
    ; If there are no nicknames left in the list then stop
    if (!%d) { return }
    ; Display the nicknames
    echo $colour(info) -ti2 $chan * $nick has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
    if (!$istok(%n,$nick,32)) {
      ; Add the current nickname to the list
      hadd trackusers $address($nick,2) %n $nick
    }
  }
  else {
    ; Create a new entry for this mask
    hadd trackusers $address($nick,2) $nick
  }
}
on *:NICK: {
  if ($hget(trackusers,$address($newnick,2))) {
    var %n = $ifmatch
    if (!$istok(%n,$newnick,32)) {
      ; Append the new nickname to the list for this mask
      hadd trackusers $address($newnick,2) %n $newnick
    }
  }
  else {
    ; Create a new entry for this mask
    hadd trackusers $address($nick,2) $newnick
  }
}
-
menu nicklist,query {
  -
  Track Users
  .View Other Nicknames:{
    if (!$address($$1,2)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
    if ($hget(trackusers,$address($$1,2))) {
      var %n = $ifmatch
      if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
      else { var %d = %n }
      if (!%d) { goto notknown }
      echo $colour(info) -ti2 # * $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
    }
    else {
      :notknown
      echo $colour(info) -ti2 # * $$1 has not been known by any other nickname
    }
  }
  ; This resets the data for this nick's mask only
  .Reset:hdel trackusers $address($$1,2)
}
ON *:EXIT: {
  ; Save data on exit
  if ($hget(trackusers)) { hsave -o trackusers trackusers.dat }

How to use

• Normally it will work auto some people will load it and say it doesnt appear the other nicknames or its not working ... i will say it working fine just load it and wait couple days so that he can recognize and save the other nicks