Clone Scanner

[Omar]

• This addon will let you see all the clones from the users in a specify channel.

Example

•   ----------------- #20_something Clones Scan ----------------
                      - Clones from E9EA8C.4376EB.DBD858.502B3B
                      - 1. Alberto (irc)
                      - 2. Bigbanana (irc)
                      - Clones from 6C196A.18A1A8.D3A2C7.967CAB
                      - 1. BaDBoY- (CSOHBET)
                      - 2. C-E-M (asdT)
                      - Clones from ABABA2.89A482.2A31DC.0993E9
                      - 1. Bonaparte_ist (Java)
                      - 2. istanbul_man (Java)
                      - Finished scanning for clones, 6 clones from 3 hosts found
                      -------------------- End Of Scan --------------------

How to load the addon on your mIRC script (choose either 1 or 2)

• 1- Go on Tools on the MenuBar - Script Editor - Remote - File - New then copy the code down and paste it there then press Ok.
  
  2- Download the Clone Scanner.mrc down, Put it on the mirc folder and go on Tools on the MenuBar - Script Editor --- > Remote - File  - Load and then choose the place of the Clone Scanner.mrc and then press Open then Ok. 

Code

Code:

alias clonescan {
  var %d = linesep $iif($active == Status Window,-s,$active)
  if ((!$chan) && (!$1)) {
    %d | echo -ca ctcp * Error: specify a channel to scan for clones! | %d
    return
  }
  if (($1) && ($1 !ischan)) {
    %d | echo -ca ctcp * Error: you are not on the channel you specified | %d
    return
  }
  set %do_clonescan $iif($1,$1,$chan)
  set %ds_clonescan $iif($active == Status Window,status,$active)
  who %do_clonescan
}

alias -l clonescan2 {
  var %i = 1,%a
  var %tc = 0,%th = 0

  var %chan = $1
  linesep %chan
  clonescan.echo -c ctcp %ds_clonescan 1-----------------4 %chan Clones Scan1 ----------------
  while (%i <= $nick(%chan,0)) {
    if ($ialchan($address($nick(%chan,%i),2),%chan,0) > 1) {
      if ($istok(%a,$remove($address($nick(%chan,%i),2),*!*@),32)) {
        inc %i
        continue
      }
      inc %th
      %a = $addtok(%a,$remove($address($nick(%chan,%i),2),*!*@),32)
      var %b = 1
      clonescan.echo -c info %ds_clonescan 1- Clones from4 $remove($address($nick(%chan,%i),2),*!*@) $+
      while (%b <= $ialchan($address($nick(%chan,%i),2),%chan,0)) {
        clonescan.echo -c info %ds_clonescan 1-1 %b  $+ . $ialchan($address($nick(%chan,%i),2),%chan,%b).nick ( $+ $ialchan($address($nick(%chan,%i),2),%chan,%b).user $+ )
        inc %b
        inc %tc
      }
    }
    inc %i
  }
  if (%tc > 0) dec %tc
  clonescan.echo -c ctcp %ds_clonescan 1-4 Finished scanning for clones, %tc clone $+ $iif(%tc != 1,s) from %th host $+ $iif(%th != 1,s) found
  echo -a -------------------- 4End Of Scan1 --------------------
  unset %ds_clonescan
}

alias -l clonescan.echo {
  if ($3 == status) echo $1 $+ s $2 $4-
  else echo $1-
}

raw 315:*: {
  if (%do_clonescan == $2) {
    unset %do_clonescan
    clonescan2 $2
    halt
  }
}

raw 352:*: if (%do_clonescan) halt

How to use:

• Just type /clonescan #channel and wait few seconds and then you will get all the clones on the channel.